:: PonxLineInstall.bat
:: GlobalPVersion= 2.03

setlocal
set LANG="fr-FR"
set SILENCE=/s

cd /dC:\
md Ponx
cd \Ponx
md temp
md bis
xcopy pasram.py bis /Y
xcopy deftaches.py bis /Y
xcopy tps.cfg bis /Y


if exist getweb.exe goto :SUIT01
echo.
echo Problème :  impossible de trouver getweb.exe
echo installation abandonnée. Corrigez avant de relancer
echo.
pause 
goto :EOF

:SUIT01
if EXIST C:\Ponx\sleepm.exe GOTO :SUIT01B
start "" /WAIT getweb http://ponx.org/download/CD/DivProg/Mci/sleepm.exe C:\Ponx

:SUIT01B
if EXIST %WINDIR%\system32\mfc71.dll GOTO :SUIT01C
start "" /WAIT getweb http://ponx.org/download/CD/annexe/mfc71.dll C:\Ponx
move C:\Ponx\mfc71.dll %WINDIR%\system32

:SUIT01C
if EXIST %WINDIR%\system32\msvcr71.dll GOTO :SUIT01D
start "" /WAIT getweb http://ponx.org/download/CD/annexe/msvcr71.dll C:\Ponx
move C:\Ponx\msvcr71.dll %WINDIR%\system32

:SUIT01D
if EXIST %WINDIR%\system32\msvcr80.dll GOTO :SUIT01E
start "" /WAIT getweb http://ponx.org/download/CD/annexe/msvcr80.dll C:\Ponx
move C:\Ponx\msvcr80.dll %WINDIR%\system32



:SUIT01E
if EXIST C:\Python25\pythonw.exe GOTO :PYTHONINSTALLED

if NOT EXIST C:\Python25\Lib\site-packages\win32com call :LOAD pywin32-212.win32-py2.5.exe

call :LOADWAIT python-2.5.2.msi
call :RUNSEUL python-2.5.2.msi

:PYTHONINSTALLED

if NOT EXIST C:\Python25\Lib\site-packages\PIL call :LOAD PIL-1.1.6.win32-py2.5.exe
if NOT EXIST C:\Python25\Lib\site-packages\win32com call :RUN pywin32-212.win32-py2.5.exe

if NOT EXIST C:\Python25\Lib\site-packages\PyRTF call :LOAD PyRTF-0_45_ponx-py25.win32.exe
if NOT EXIST C:\Python25\Lib\site-packages\PIL call :RUN PIL-1.1.6.win32-py2.5.exe

if NOT EXIST C:\Python25\Lib\site-packages\pyodbc.pyd call :LOAD pyodbc-2.0.58.win32-py2.5.exe
if NOT EXIST C:\Python25\Lib\site-packages\PyRTF call :RUN PyRTF-0_45_ponx-py25.win32.exe

if NOT EXIST C:\Python25\Lib\site-packages\pyodbc.pyd call :RUN pyodbc-2.0.58.win32-py2.5.exe


start "" /WAIT getweb http://ponx.org/download/CD/PONX/ponx.zip C:\Ponx
zipmci.py -e ponx.zip *.*

if EXIST C:\Windows\System32\AutoItX3.dll GOTO :AUTOITINSTALLED
start "" /WAIT getweb http://ponx.org/download/CD/COMdll/AutoItX3.dll C:\Ponx
move C:\Ponx\AutoItX3.dll %WINDIR%\system32

:AUTOITINSTALLED
regsvr32.exe %WINDIR%\system32\AutoItX3.dll %SILENCE%

:: pour Direct-Animation
pushd .
cd /D%windir%\system32
regsvr32 danim.dll /s
%windir%\System32\reg.exe DELETE "HKLM\SOFTWARE\Microsoft\Internet Explorer\ActiveX Compatibility\{B6FFC24C-7E13-11D0-9B47-00C04FC2F51D}" /v "Compatibility Flags" /f
popd


xcopy bis\pasram.py /Y
xcopy bis\deftaches.py /Y
xcopy bis\tps.cfg /Y


cd /DC:\Ponx
rd temp /s /q

ponx.py
PonxTest101.exe
cd /DC:\Ponx
call pluiefinstall.bat
sleepm 2000
call autoitLineInstall.bat
sleepm 2000

cd /DC:\Ponx
ponxmajversions.py




endlocal
exit
goto :EOF




:RUN
:ATTENDRUN
sleepm 500
if not exist C:\Ponx\%* GOTO :ATTENDRUN
move C:\Ponx\%* C:\Ponx\temp

:RUNSEUL
start "" /WAIT C:\Ponx\temp\%*
goto :EOF


:LOAD
start "" getweb http://ponx.org/download/CD/Python/%* C:\Ponx
:ATTENDLOAD
sleepm 250
goto :EOF


:LOADWAIT
start "" /WAIT getweb http://ponx.org/download/CD/Python/%* C:\Ponx\temp
sleepm 250
goto :EOF